REM -- H2XMAR.BAT - 31.0 PGO/MARINE POWER(EPC) INTFC - 1997FEB07VM/2007AUG03VM
@ECHO OFF
REM -- COPYRIGHT (C) 1997-1999,2000-2007 H.W.PETER, WUPPERTAL .DE --
REM -- COPYRIGHT (C) 1997-1999,2000-2007 PETER+GEISENDORF GMBH, SPROCKHOEVEL .DE --
REM -- \\UFN=OK, 2002OCT18PE

REM -- EPCSENSE=*=C:\MIDASWIN\DMSIN\PRTORDER.TXT
REM -- EPCSENSE=!

IF "%1"=="OQX" GOTO OQX
IF "%1"=="FT"  GOTO OQX

ECHO ----------------------------------------------------------
ECHO %0:
ECHO INVALID CONTEXT CALL
ECHO UNGUELTIGER AUFRUF
ECHO ----------------------------------------------------------
ECHO %0 %1 %2 %3 %4 %5 %6 %7 %8 %9
PAUSE
GOTO ENDUP

REM 
REM -- H2XMAR.BAT - OQX order queue transfer to MARINE POWER --

:OQX
rem -- %0=H2XMAR %1=OQX/FT *%2=homedisk *%3=homepath --
rem -- %4=OQ*.MAR file id --

:OQX2
rem -- create valid directory entry for data export --
IF     EXIST C:\PGEXPORT\*.*      GOTO OQX20
IF     EXIST C:\PGEXPORT\NUL:     GOTO OQX20
IF     EXIST C:\PGEXPORT\NUL      GOTO OQX20
MD           C:\PGEXPORT
:OQX20
CLS

rem -- post file(s) to transfer --
:OQX4
IF     EXIST OQ*.MAR  GOTO OQX42
ECHO -------------------------------------------------
ECHO -- HINWEIS: 
ECHO -- Es stehen keine NEUEN Order-Bestaende zur
ECHO -- Uebertragung zur Verfuegung.
ECHO --
GOTO OQX46

:OQX42
IF     EXIST C:\PGEXPORT\MPEQORD.TXT DEL C:\PGEXPORT\MPEQORD.TXT
REM                                   >  C:\PGEXPORT\MPEQORD.TXT
FOR %%A IN  (OQ*.MAR)     DO TYPE %%A >> C:\PGEXPORT\MPEQORD.TXT
DEL          OQ*.MAR
GOTO OQX46

:OQX46
DIR          C:\PGEXPORT\MPEQORD.TXT
ECHO -------------------------------------------------
ECHO %0 - ET-Order:
ECHO -- Die zu uebertragende Datei finden Sie
ECHO -- auf diesem Computer im Verzeichnis C:\PGEXPORT
ECHO -- unter dem Namen  MPEQORD.TXT (s.o.)
ECHO -- fuer den elektronischen Versand bereitgestellt
ECHO --                                      ...RETURN
ECHO -------------------------------------------------
PAUSE >NUL:

:OQX6
rem -- try to call link procedure --
IF     EXIST H2XMAR.HTM GOTO OQX60
GOTO OQX68
:OQX60
START        H2XMAR.HTM
GOTO OQX68
:OQX68
rem -- CD \
GOTO OQXEND

:OQXEND
GOTO ENDUP

REM 
REM -- H2XMAR.BAT - FINAL --

:ENDUP
SET PGOEPCPI=

REM -- now return to PGO home drive and resume PGO mainline --
rem -- %2
rem -- CD \
rem -- CD %3
SET  PGOEPCPI=PGOBEG
IF "%PGONETID%"=="W10" SET PGOEPCPI=START /R /MAX PGOFFICE.PIF
IF "%PGONETID%"=="W16" SET PGOEPCPI=START /R /MAX PGOFFICE.PIF
IF "%PGONETID%"=="W95" SET PGOEPCPI=START /R /MAX PGOFFICE.PIF
IF "%PGOEPCEX%"=="END" SET PGOEPCPI=
%PGOEPCPI%
EXIT
